EAでオブジェクトを作成して値が取れない問題

EA内でオブジェクトを作成した後に値を取得したいという場面。

MQL4で以下のコードを書く。

#property copyright "nisai"
#property link      "https://nisaifx.com"
#property version   "1.00"
#property strict

string objName="obj";
int count=0;

int OnInit(){
   return(INIT_SUCCEEDED);
}

void OnTick(){
   Print("count:",count);
   ObjectCreate(0,objName,OBJ_TREND,0,iTime(NULL,PERIOD_CURRENT,60),1.06,iTime(NULL,PERIOD_CURRENT,10),1.068);
   ObjectSetInteger(0,objName,OBJPROP_COLOR,clrYellow);
   ObjectSetInteger(0,objName,OBJPROP_RAY_RIGHT,true);
   ObjectSetInteger(chart_id,obj_name,OBJPROP_SELECTED,true);
   int windowNumber=ObjectFind(0,objName);
   if(windowNumber>=0){
      Print("object found:", windowNumber);
      double value=ObjectGetValueByTime(0,objName,iTime(NULL,PERIOD_CURRENT,0),0);
      Print("value:", value);
      ExpertRemove();
   }
   count++;
}

メインチャート(チャート番号:0)に対して、トレンドライン(OBJ_TREND)を作成する。
オブジェクトが作成されたことを確認できたら、現在バーの位置の値を取得し、これを表示してEAを削除する。
何回OnTickが動いたかも表示させる。

走らせてみる。オブジェクトがどのように作成されるかを見るためにビジュアルモードをONにする。

チャートにはトレンドラインが表示された。

OnTickは1度だけ実行された(オブジェクト作成後、すぐに参照が可能)。
オブジェクトは問題なく作成され、値「1.0696」が表示された。

オブジェクトを線形回帰チャネル(OBJ_REGRESSION)に変更してみる。

#property copyright "nisai"
#property link      "https://nisaifx.com"
#property version   "1.00"
#property strict

string objName="obj";
int count=0;

int OnInit(){
   return(INIT_SUCCEEDED);
}

void OnTick(){
   Print("count:",count);
   ObjectCreate(0,objName,OBJ_REGRESSION,0,iTime(NULL,PERIOD_CURRENT,60),0,iTime(NULL,PERIOD_CURRENT,10),0);
   ObjectSetInteger(0,objName,OBJPROP_COLOR,clrYellow);
   ObjectSetInteger(0,objName,OBJPROP_RAY_RIGHT,true);
   ObjectSetInteger(0,objName,OBJPROP_SELECTED,true);
   int windowNumber=ObjectFind(0,objName);
   if(windowNumber>=0){
      Print("object found:", windowNumber);
      double value=ObjectGetValueByTime(0,objName,iTime(NULL,PERIOD_CURRENT,0),0);
      Print("value:", value);
      ExpertRemove();
   }
   count++;
}

チャネルが描画された。

トレンドラインの時同様にオブジェクトは作成され、すぐに参照可能になったが値が取れていない。

オブジェクトが存在しない場合は作成、存在する場合は値を取得して、値が0以外であればEAを削除するように書き換える。
(オブジェクトを作成したティックでは参照を行わない)

#property copyright "nisai"
#property link      "https://nisaifx.com"
#property version   "1.00"
#property strict

string objName="obj";
int count=0;

int OnInit(){
   return(INIT_SUCCEEDED);
}

void OnTick(){
   Print("count:",count);
   int windowNumber=ObjectFind(0,objName);
   if(windowNumber<0){
      ObjectCreate(0,objName,OBJ_REGRESSION,0,iTime(NULL,PERIOD_CURRENT,60),0,iTime(NULL,PERIOD_CURRENT,10),0);
      ObjectSetInteger(0,objName,OBJPROP_COLOR,clrYellow);
      ObjectSetInteger(0,objName,OBJPROP_RAY_RIGHT,true);
      ObjectSetInteger(0,objName,OBJPROP_SELECTED,true);
   }else{
      Print("object found:", windowNumber);
      double value=ObjectGetValueByTime(0,objName,iTime(NULL,PERIOD_CURRENT,0),0);
      Print("value:", value);
      if(value>0){
         ExpertRemove();
      }
   }
   count++;
}

今度は値が取得できた。
ただ、今回は2度目のOnTickで取得できたが、必ず2度目に取得できるわけではない。
リファレンス(https://docs.mql4.com/objects/objectcreate)には、ObjectCreateが非同期であることが書いてある(MQL5も同様)。
リファレンスによると、ObjectCreateの戻り値ではなくObjectFindなどを用いるように書いてあるが、前述の通り値が取れるとは限らない。

テスター上、EAの処理と非同期のオブジェクト作成処理が同期していないため、ビジュアルモードの速度が影響することになる。
テスターがゆっくり動いていれば、オブジェクト作成後、次のOnTickで値が取得できるだろう。

また、謎の落とし穴がもう一つあって、ビジュアルモードのON/OFF自体がオブジェクト作成処理に影響している場合がある。
MT4で前述のテストをする場合、トレンドラインを作成・表示する処理はビジュアルモードがOFFであっても値を取得できるが、線形回帰チャネルはいつまで待っても取得できない。
できるオブジェクトとできないオブジェクトがあるという事だが、どこに線引きがあるのかは知らない。

ただし、MT5で同様のテストをする場合、ビジュアルモードのON/OFFに関わらずどちらも取得できる(なんなら線形回帰チャネルであっても作成後即取得でき、非同期であるという意識をしないかもしれない)。

まとめ

とりあえずMT4ユーザーは早くMT5に乗り換えよう。
ただ、EAでオブジェクトを扱うのは色々と面倒くさい。作ったり消したり、それらの処理が非同期だったり。
オブジェクトに頼らずに計算した方が、間違いなく安全なプログラムにはなるだろうと思う。
オブジェクトは、あくまで人の目に見せるためだけに使おう。